The SICI code is composed of three segments: Item, Contribution, and Control.
For a complete description the reader is referred to the ANSI/NISO Z39.56-1996
standard. This record provides a high-level description only; the syntax is
declared as an ABNF rule set (see below).
		

The SICI is a combination of defined segments, all of which are required.
These segments are:
(a) Item Segment, the data elements needed to describe the serial item (ISSN,
    Chronology, Enumeration);
(b) Contribution Segment, the data elements needed to identify contributions
    within an item (Location, Title Code, and other numbering schemes in a
    specific instance of the SICI);
(c) Control Segment, the data elements needed to record those administrative
    elements that determine the validity, version, and format of the code
    representation.
The Control Segment (c)  is the most important segment of the SICI.
Interpretation and processing are determined by the Control Segment.

(a) The Item Segment is always the first segment in the SICI. It identifies
    the Serial Item and is delimited from the Contribution Segment by the left
    angle bracket (<). The Item Segment at minimum must contain an ISSN. All
    available chronology and enumeration information must be used.

(b) The Contribution Segment combined with the Item Segment and the Control
    Segment make up the Contribution Identifier. The Contribution Segment is
    used to identify the starting location of the contribution within the
    specified item and the Title Code that further distinguishes that
    contribution. The Contribution Segment is delimited from the Item Segment
    and the Control Segment by a pair of angle brackets (<>). Within the
    Contribution Segment the Location is separated from the Title Code by a
    colon. When using a CSI-3 a second colon is used to introduce the locally
    assigned number.

(c) The Control Segment is always the last segment in the SICI. It is
    administrative in nature and is separated from the Contribution Segment by
    the right angle bracket (>). The lengths of the data elements in the
    Control Segment currently are as follows: CSI is one (1), DPI one (1), MFI
    two (2), Standard Version Number one (1) and Check Character one (1). This
    standard does not fix the lengths of these data elements so that additional
    codes may be added as needed by the maintenance agency. Parsing of the
    Control Segment should be through the use of delimiters and not by the
    length of the data elements.

This specification uses the Augmented Backus-Naur Form notation of RFC 2234.
Below is given an ABNF rule set for producing a SICI code:

  ; ABNF for SICI - Serial Item and Contribution Identifier

  SICI = item-segment contribution-segment control-segment

  item-segment = issn chronology  enumeration
  contribution-segment = "<" location [ ":" title-code [ ":" local-number ] ] ">"
  control-segment = csi "." dpi "." mfi ";" version "-" check-char

  ; item-segment components
  issn = 4DIGIT [ "-" ] 3DIGIT ( DIGIT / "X" )
  chronology = "(" [ 4*8DIGIT [ "/" 4*8DIGIT ] ] ")"
  enumeration = [ 1*( DIGIT / UPPER / "/" ) *( ":" 1*( DIGIT / UPPER / "/" ) ) ] [ ( "+" / "*" ) ]

  ; contribution-segment components
  location = *CHARS
  title-code = *6( CHARS / DELIM )
  local-number = *CHARS

  ; control-segment components
  csi = ; code structure identifier
        "1" /  ; serial item identifier
        "2" /  ; serial contribution identifier
        "3"    ; other

  dpi = ; derivative part identifier
        "0" /  ; serial item or contribution
        "1" /  ; table of contents
        "2" /  ; index
        "3"    ; abstract

  mfi = ; medium/format identifier
        "TX" / ; printed text
        "TL" / ; printed text, looseleaf
        "TH" / ; printed text, hardbound
        "TS" / ; printed text, softcover
        "TB" / ; braille
        "CD" / ; computer-readable optical media (CD-ROM)
        "CF" / ; computer-readable magnetic disk media
        "CT" / ; computer-readable magnetic tape media
        "CO" / ; online (remote)
        "HE" / ; microfiche
        "HD" / ; microfilm
        "SC" / ; sound recording
        "VX" / ; video recording
        "ZN" / ; multiple physical forms
        "ZU" / ; physical form unknown
        "ZZ"   ; other

  version = ; version number
        "1" /  ; Z39.56-1991
        "2"    ; Z39.56-1996

  check-char = DIGIT / UPPER / "#"

  CHARS = DIGIT / UPPER /
    "&" / "'" / "*" / "\" / "}" / ")" / "]" / "," / "@" / "$" /
    "=" / "!" / "-" / "#" / "{" / "(" / "[" / "%" / "." / "+" /
    "?" / '"' / ";" / "/" / "^" / "`" / "~" / "_" / "|"

  DELIM = ":" / "<" / ">"
  DIGIT = %x30-39 ; 0-9
  UPPER = %x41-5A ; A-Z

The SICI code is represented in uppercase form. Allowable characters are given
in the CHARS and DELIM productions in the ABNF given above, and are a subset of
the 7-bit ASCII character set.